FloodFrame

The FloodFrame method floods area of the specified frame with given color.

FloodFrame Track,Frame,Color

Parameters

Track: Zero-based track number.
Frame: Zero-based frame number.
Color: Hexadecimal text color value "RRGGBB".

Note

This method can be applied to any frame on dynamic animation track. It fill the whole frame with specified color. The color is opaque (transparency information for that frame is lost).

Example

This .vbs script draws a "yellow flash" on the background if gif animation in the middle of movie:

Source image	Result


Set ani = CreateObject("ShotGraph.GifAnimator")

flashtime = 10
flashcount = 2
filename = "c:\images\flash1.gif"

ani.GetFileDimensions filename,width,height
' Track #0
ani.AddTrack width,height
ani.Loop(0) = False
' Track #1
ani.Read filename
commontime = 0
For i=0 to ani.FramesCount(1)-1
	commontime = commontime + ani.Delay(1,i)
Next

common_flash_time = flashtime * (2 * flashcount - 1)
if commontime < common_flash_time then Wscript.Quit
ani.AddFrame 0,1,(commontime - common_flash_time) / 2

For i=1 to flashcount
	ani.AddFrame 0,1,flashtime
	ani.FloodFrame 0,ani.FramesCount(0)-1,"ffff33"
	ani.AddFrame 0,1,flashtime
Next
ani.AddFrame 0,1,flashtime

ani.Join
ani.Play "c:\images\flash.gif"